FGFW5: Visual Basic Version

'*****************************************************************************
'                                                                            *
'  FGFW5.frm                                                                 *
'                                                                            *
'  Demonstrate how to display centered text within a rectangle.              *
'                                                                            *
'*****************************************************************************
Dim hPal As Long
Dim hVB As Long
Dim cxClient As Long, cyClient As Long
Private Sub Form_Activate()
   Call fg_realize(hPal)
   Refresh
End Sub
Private Sub Form_Load()
   Dim dx As Long, dy As Long
   Dim xMid As Long, yMid As Long
   ScaleMode = 3
   Call fg_setdc(hDC)
   hPal = fg_defpal()
   Call fg_realize(hPal)
   Call fg_vbinit
   hVB = fg_vballoc(640, 480)
   Call fg_vbopen(hVB)
   Call fg_vbcolors
   If fgf_load(App.Path & "\AUSTIN36.FGF") = 0 Then
      Call MsgBox("Unable to load font file.", vbCritical, "Error")
      Unload Me
      Exit Sub
   End If
   
   Call fg_setcolor(255)
   Call fg_fillpage
   xMid = fg_getmaxx() / 2
   yMid = fg_getmaxy() / 2
   MessageText = "TEXT IN A BOX"
   dx = fgf_width(MessageText, 13) / 2 + 4
   dy = fgf_height(MessageText, 13) / 2 + 4
   Call fg_setcolor(17)
   Call fg_rect(xMid - dx, xMid + dx, yMid - dy, yMid + dy)
   Call fg_setcolor(20)
   Call fg_move(xMid, yMid)
   Call fgf_justify(0, 0)
   Call fgf_print(MessageText, 13)
End Sub
Private Sub Form_Paint()
   Call fg_vbscale(0, fg_getmaxx(), 0, fg_getmaxy(), 0, cxClient - 1, 0, cyClient - 1)
End Sub
Private Sub Form_Resize()
   cxClient = ScaleWidth
   cyClient = ScaleHeight
   Refresh
End Sub
Private Sub Form_Unload(Cancel As Integer)
   Call fgf_unload(-1)
   Call fg_vbclose
   Call fg_vbfree(hVB)
   Call fg_vbfin
End Sub