FGIW4: Visual Basic Version

'*****************************************************************************
'                                                                            *
'  FGIW4.frm                                                                 *
'                                                                            *
'  Demonstrate how to retrieve a PCX file from an FGI library and display it *
'  later.                                                                    *
'                                                                            *
'*****************************************************************************
Dim hPal As Long
Dim hVB As Long, hFGI As Long
Dim cxClient As Long, cyClient As Long
Private Sub Form_Activate()
   Call fg_realize(hPal)
   Refresh
End Sub
Private Sub Form_Load()
   Dim Buffer() As Byte
   Dim BuffSize As Long
   ScaleMode = 3
   Call fg_setdc(hDC)
   hPal = fg_defpal()
   Call fg_realize(hPal)
   Call fg_vbinit
   hVB = fg_vballoc(320, 200)
   Call fg_vbopen(hVB)
   Call fg_vbcolors
   hFGI = fgi_open(App.Path & "\EXAMPLE.FGI")
   If hFGI = 0 Then
      Call MsgBox("Unable to open FGI file.", vbCritical, "Error")
      Unload Me
      Exit Sub
   End If
   BuffSize = fgi_filesize("CLOUDS.PCX", hFGI)
   ReDim Buffer(BuffSize)
   Call fgi_read("CLOUDS.PCX", Buffer(0), hFGI)
   Call fg_imagebuf(Buffer(0), BuffSize)
   Call fg_showpcx("", FG_AT_XY + FG_FROMBUFFER)
   Call fg_imagebuf(Buffer(0), 0)
   Erase Buffer
   Call fgi_close(hFGI)
End Sub
Private Sub Form_Paint()
   Call fg_vbscale(0, fg_getmaxx(), 0, fg_getmaxy(), 0, cxClient - 1, 0, cyClient - 1)
End Sub
Private Sub Form_Resize()
   cxClient = ScaleWidth
   cyClient = ScaleHeight
   Refresh
End Sub
Private Sub Form_Unload(Cancel As Integer)
   Call fg_vbclose
   Call fg_vbfree(hVB)
   Call fg_vbfin
End Sub